@echo off
title TuTiTuCraft Mod Setup
set /p install=Is fabric MC 1.21 installed? [Y/N]:
if not exist %temp%\TuTiTuCraft md %temp%\TuTiTuCraft
if /i not '%install%'=='n' goto :mods
cls
echo Downloading installer . . .
if not exist %temp%\TuTiTuCraft\fabric-installer.exe powershell -c "Invoke-WebRequest -Uri 'https://maven.fabricmc.net/net/fabricmc/fabric-installer/1.0.1/fabric-installer-1.0.1.exe' -OutFile '%temp%\TuTiTuCraft\fabric-installer.exe'"
call :error
cls
echo 1. Wait for window . . .
echo 2. Set "Minecraft Version" to "1.21"
echo 3. DO NOT change any other options and press "install"
echo 4. After install is complete, close the installer
start /w %temp%\TuTiTuCraft\fabric-installer.exe

:mods
cls
echo Downloading old mod names . . .
powershell -c "Invoke-WebRequest -Uri 'https://hersheylightning.com/mod/expired.txt' -OutFile '%temp%\TuTiTuCraft\old'"
call :error
cls
echo Deleting old mods . . .
for /f "usebackq" %%I in ("%temp%\TuTiTuCraft\old") do del "%appdata%\.minecraft\mods\%%I.jar"
cls
echo Downloading new mods . . .
powershell -c "Invoke-WebRequest -Uri 'https://hersheylightning.com/mod/mods.zip' -OutFile '%temp%\TuTiTuCraft\mods.zip'"
call :error
cls
echo Extracting new mods . . .
powershell -c "Expand-Archive '%temp%\TuTiTuCraft\mods.zip' '%appdata%\.minecraft\mods' -Force"
cls
echo All mods downloaded, have fun!
pause
goto:eof

:error
if %ERRORLEVEL% neq 0 (
	echo an error has occured!
	echo try to check your internet connection
	pause
	exit
)