@echo off
title TuTiTuCraft Mod Setup
set /p install=Is fabric MC 1.21.1 0.16.14 installed? [Y/N]:
if not exist %temp%\TuTiTuCraft md %temp%\TuTiTuCraft
if /i not '%install%'=='n' goto :mods
cls
echo Downloading installer . . .
if not exist %temp%\TuTiTuCraft\fabric-installer.exe powershell -c "Invoke-WebRequest -Uri 'https://maven.fabricmc.net/net/fabricmc/fabric-installer/1.0.1/fabric-installer-1.0.1.exe' -OutFile '%temp%\TuTiTuCraft\fabric-installer.exe'"
call :error
cls
echo 1. Set "Minecraft Version" to "1.21.1"
echo 2. Set "Loader Version" to "0.16.14"
echo 3. DO NOT change any other options and press "install"
echo 4. After install is complete, close the installer
echo Press any key to open installer . . .
pause >nul
start /w %temp%\TuTiTuCraft\fabric-installer.exe

:mods
cls
echo Downloading delete index . . .
powershell -c "Invoke-WebRequest -Uri 'https://hersheylightning.com/download/expired.txt' -OutFile '%temp%\TuTiTuCraft\old'"
call :error
cls
echo Deleting old mods . . .
for /f "usebackq" %%I in ("%temp%\TuTiTuCraft\old") do del "%appdata%\.minecraft\mods\%%I.jar"
cls
echo Downloading mod index . . .
powershell -c "Invoke-WebRequest -Uri 'https://hersheylightning.com/download/index.txt' -OutFile '%temp%\TuTiTuCraft\index'"
call :error
cls
echo Searching for mods to download . . .
for /f "usebackq" %%I in ("%temp%\TuTiTuCraft\index") do if not exist %appdata%\.minecraft\mods\%%I.jar (
	cls
	echo Downloading %%I.jar
	powershell -c "Invoke-WebRequest -Uri 'https://hersheylightning.com/download/mods/%%I.jar' -OutFile '%appdata%\.minecraft\mods\%%I.jar'"
	call :error
	cls
	echo Searching for more mods to download . . .
)
cls
echo Downloading configurations . . .
powershell -c "Invoke-WebRequest -Uri 'https://hersheylightning.com/download/config.zip' -OutFile '%temp%\TuTiTuCraft\config.zip'"
call :error
cls
echo Extracting configurations . . .
powershell -c "Expand-Archive '%temp%\TuTiTuCraft\config.zip' '%appdata%\.minecraft\config' -Force"
cls
echo All mods setup, have fun!
echo Press any key to close installer . . .
pause >nul
goto:eof

:error
if %ERRORLEVEL% neq 0 (
	echo A download error has occured!
	echo Try to check your internet connection
	pause
	exit
)